pbm
---

   Several options may be set in the PBMplus driver.

   Syntax:
            set terminal pbm {<fontsize>} {<colormode>}

   where <fontsize> is `small', `medium', or `large' and <colormode> is
`monochrome', `gray' or `color'.  Default size is 640 pixels wide and 480
pixels high.  The output for `monochrome' is a portable bitmap (one bit per
pixel).  The output for `gray' is a portable graymap (three bits per pixel).
The output for `color' is a portable pixmap (color, four bits per pixel).  The
output of these drivers can be used with Jef Poskanzer's excellent PBMPLUS
package which provides programs to convert the above PBMPLUS formats to GIF,
TIFF, MacPaint, Macintosh PICT, PCX, X11 bitmap and many others.

   Examples:

            set term pbm small
            set size 2,2
            set term pbm color medium

pcl5
----

   Three options may be set in the pcl5 driver.  The driver actually uses
HPGL-2 but there is a name conflict among the terminal devices.

   Syntax:
            set terminal pcl5 {<mode>} {<font>} {<fontsize>}

   where <mode> is `landscape', or `portrait', <font> is `stick', `univers', or
`cg_times', and fontsize is the size in points.
            set terminal pcl5 landscape

postscript
----------

   Several options may be set in the PostScript driver.

   Syntax:
            set terminal postscript {<mode>} {<color>} {<dashed>}
                                    {"<fontname>"} {<fontsize>}

   where <mode> is `landscape', `portrait', `eps' or `default'.  Selecting
default sets all options to their defaults.  <color> is either `color' or
`monochrome'.  <dashed> is either `solid' or `dashed'.  "<fontname>" is the
name of a valid PostScript font.  <fontsize> is the size of the font in
PostScript points.  Defaults are `landscape', `monochrome', `dashed',
"Helvetica", and 14pt.  Default size of PostScript plot is landscape mode 10
inches wide and 7 inches high.

   To get EPS output, use the `eps' mode and make only one plot per file.  In
`eps' mode the whole plot is halved in size; the fonts are half the given size,
and the plot is 5 inches wide and 3.5 inches high.

   Examples:

            set term postscript default       # old postscript
            set term postscript landscape 22  # old psbig
            set term postscript eps 14   # old epsf1
            set term postscript eps 22   # old epsf2
            set size 0.7,1.4
            set term post portrait color "Times-Roman" 14

regis
-----

   The `regis' terminal device has the option of using 4 or 16 colors.  The
default is 4.  For example:
           set term regis 16

table
-----

   Instead of producing a picture, term type `table' prints out the evaluation
results in a multicolumn ASCII table of X Y Z values.  For those times when you
really want to see the numbers, now you can see them on the screen or save to a
file.

windows
-------

   Three options may be set in the windows driver.

   Syntax:
            set terminal windows {<color>} {"<fontname>"} {<fontsize>}

   `<color>' is either `color' or `monochrome'.  `"<fontname>"' is the name of
a valid Windows font.  `<fontsize>' is the size of the font in points.

   The `gnuplot graph' window has the following options on a pop up menu
accessed by pressing the right mouse button or selecting `Options' from the
system menu:

   `Bring to Top' when checked brings the graph window to the top after every
plot.

   `Color' when checked enables color linestyles.  When unchecked it forces
monochrome linestyles.

   `Copy to Clipboard' copies a bitmap and a Metafile picture.

   `Background...' sets the window background color.

   `Choose Font...' selects the font used in the graphics window.

   `Line Styles...' allows customization of the line colors and styles.

   `Print...' prints the graphics windows using a Windows printer driver and
allows selection of the printer and scaling of the output.  The output produced
by `Print' is not as good as that from gnuplot's own printer drivers.

   `Update wgnuplot.ini' saves the current window locations, window sizes, text
window font, text window font size, graph window font, graph window font size,
background color and linestyles to the initialisation file `WGNUPLOT.INI'.

   In order of preference, graphs may be be printed in the following ways.

   `1.' Use the gnuplot command `set terminal' to select a printer and `set
output' to redirect output to a file.

   `2.' Select the `Print...' command from the `gnuplot graph' window.  An
extra command `screendump' does this from the text window.

   `3.' If `set output "PRN"' is used, output will go to a temporary file.
When you exit from gnuplot or when you change the output with another `set
output' command, a dialog box will appear for you to select a printer port.  If
you choose OK, the output will be printed on the selected port, passing
unmodified through the print manager.  It is possible to accidently (or
deliberately) send printer output meant for one printer to an incompatible
printer.

   The `gnuplot text' window has the following options on a pop up menu
accessed by pressing the right mouse button or selecting `Options' from the
system menu:

   `Copy to Clipboard' copies marked text to the clipboard.

   `Paste' copies text from the clipboard as if typed by the user.

   `Choose Font...' selects the font used in the text window.

   `System Colors' when selected makes the text window honor the System Colors
set using the Control Panel.  When unselected, text is black or blue on a white
background.

   `Update wgnuplot.ini' saves the current text window location, text window
size, text window font and text window font size to the initialisation file
`WGNUPLOT.INI'.

   `MENU BAR'

   If the menu file `WGNUPLOT.MNU' is found in the same directory as
WGNUPLOT.EXE, then the menu specified in `WGNUPLOT.MNU' will be loaded.

   Menu commands are:
      [Menu]       Start a new menu with the name on the following line
      [EndMenu]    End current menu.
      --           Insert a horizontal menu separator
      |            Insert a vertical menu separator
      [Button]     Put next macro on a push button instead of a menu.

   Macros take two lines with the macro name (menu entry) on the first line and
the macro on the second line.  Leading spaces are ignored.

   Macros commands are:
      [INPUT]      Input string with prompt terminated by [EOS] or {ENTER}
      [EOS]        End Of String terminator.  Generates no output.
      [OPEN]       Get name of file to open from list box, with title of
                   list box terminated by [EOS], followed by default
                   filename terminated by [EOS] or {ENTER}
                   This uses COMMDLG.DLL from Windows 3.1.
      [SAVE]       Get name of file to save.  Similar to [OPEN]

   Macros character substitutions are:
      {ENTER}      Carriage Return '\r'
      {TAB}        Tab     '\011'
      {ESC}        Escape  '\033'
      {^A}         '\001'
      ...
      {^_}         '\031'

   Macros are limited to 256 characters after expansion.

   Windows gnuplot will read some of its options from the `[WGNUPLOT]' section
of `WGNUPLOT.INI' in the Windows directory.  An example `WGNUPLOT.INI' file is
shown below.
     [WGNUPLOT]
     TextOrigin=0 0
     TextSize=640 150
     TextFont=Terminal,9
     GraphOrigin=0 150
     GraphSize=640 330
     GraphFont=Arial,10
     GraphColor=1
     GraphToTop=1
     GraphBackground=255 255 255
     Border=0 0 0 0 0
     Axis=192 192 192 2 2
     Line1=0 0 255 0 0
     Line2=0 255 0 0 1
     Line3=255 0 0 0 2
     Line4=255 0 255 0 3
     Line5=0 0 128 0 4
   The `GraphFont' entry specifies the font name and size in points.  The 5
numbers given in the `Border', `Axis' and `Line' entries are the `Red'
intensity (0-255), `Green' intensity, `Blue' intensity, `Color Linestyle' and
`Mono Linestyle'.  `Linestyles' are 0=SOLID, 1=DASH, 2=DOT, 3=DASHDOT,
4=DASHDOTDOT.  In the example `WGNUPLOT.INI' file above, Line 2 is a green solid
line in color mode, or a dashed line in monochrome mode.  The default line
width is 1 pixel.  If `Linestyle' is negative it specifies the width of a SOLID
line in pixels.  Line1 and any linestyle used with the `points' style must be
SOLID with unit width.

   Windows 3.1 is preferred, but WGNUPLOT will run under Windows 3.0 with the
following restrictions:

   `1.' COMMDLG.DLL and SHELL.DLL (available with Windows 3.1 or Borland C++
3.1) must be in the windows directory.

   `2.' WGNUPLOT.HLP produced by Borland C++ 3.1 is in Windows 3.1 format.  You
need to use the WINHELP.EXE supplied with Borland C++ 3.1.

   `3.' It won't run in real mode due to lack of memory.

   `4.' Truetype fonts are not available in the graph window.

   `5.' Drag-drop does not work.

set tics
========

   By default, tics are drawn inwards from the border on all four sides.  The
`set tics' command can be used to change the tics to be drawn outwards on the
left and bottom borders only.  This is useful when doing impulse plots.

   Syntax:
            set tics {<direction>}
            show tics

   where <direction> may be `in' or `out'. `set tics' defaults to `in'.

   See also the `set xtics', `set ytics', and `set ztics' command for more
control of tic marks.  Using splot, in 3-d plots, one can adjust the relative
height of the vertical (Z) axis using `set ticslevel'. The numeric argument
provided specifies the location of the bottom of the scale. a zero will put it
on the bottom grid and any positive number somewhere along the z axis.

   Syntax:
            set ticslevel {<level>}
            show tics

   where <level> is a non negative numeric argument. For example,

            set ticslevel 0.5

   sets the tics level to the default value.

   See also the `set view'.

set time
========

   The optional `set time' places the time and date of the plot either at the
top or bottom of the left margin. The exact location is device dependent.

   Syntax:
            set time {<xoff>}{,<yoff>}
            set notime
            show time

   Specifying constants <xoff> or <yoff> as optional offsets for the time will
move the time <xoff> or <yoff> character screen coordinates. For example,

            set time ,-3

   will change only the y offset of the time, moving the title down by roughly
the height of three characters.

set title
=========

   The `set title' command produces a plot title that is centered at the top of
the plot. Using the optional x,y screen offsets, the title can be placed
anywhere on the plot. `set title' with no parameters clears the title.

   Syntax:
             set title {"<title-text>"} {<xoff>}{,<yoff>}
             show title

   Specifying constants <xoff> or <yoff> as optional offsets for the title will
move the title <xoff> or <yoff> character screen coordinates. Note these are
screen coordinates and not plot coordinates. For example,

             set title ,-1

   will change only the y offset of the title, moving the title down by roughly
the height of one character.

   (The EEPIC, Imagen, LaTeX, and TPIC drivers allow \\ in a string to specify
a newline.)

set trange
==========

   The `set trange' command sets the parametric range used to compute x and y
values when in parametric mode. If not in parametric mode (see `set
parametric') then this range is not used. This command does not affect x/y
autoscaling or x/y ranges.

   This range may also be specified on the `plot' command line when in
parametric mode.

   Syntax:
            set trange [{<tmin> : <tmax>}]

   where <tmin> and <tmax> terms are constants or expressions.

   Both the <tmin> and <tmax> terms are optional. Anything omitted will not be
changed, so
            set trange [:10]
   changes tmax to 10 without affecting tmin.  See also `set urange' and `set
parametric'.

set urange
==========

   The `set urange' and `set vrange' commands sets the parametric ranges used
to compute x, y, and z values when in `splot' parametric mode. If not in
parametric mode (see `set parametric') then these ranges are not used. This
command does not affect x/y autoscaling or x/y ranges.

   This range may also be specified on the `splot' command line when in
parametric mode.  See `plot' for more information

   Syntax:
            set urange [{<umin> : <umax>}]

   where <umin> and <umax> terms are constants or expressions.

   Both the <umin> and <umax> terms are optional. Anything omitted will not be
changed, so
            set urange [:10]
   changes umax to 10 without affecting umin.  See also `set trange'.

set variables
=============

   The `show variables' command lists all user-defined variables and their
values.

   Syntax:
            show variables

set view
========

   The `set view' command sets the view point for `splot's. This command
controls the way the 3-d coordinates of the plot are mapped into the 2-d screen
space. This command provides controls to both rotation and scaling of the
plotted data but supports orthographic projections only.

   Syntax:
            set view <rot_x> {,{<rot_z>}{,{<scale>}{,<scale_z>}}}
            show view

   where <rot_x> and <rot_z> control the rotation angles (in degrees) along a
virtual 3-d coordinate system aligned with the screen such that the screen
horizontal axis is x, screen vertical axis is y, and the axis perpendicular to
the screen is z. <rot_x> is bounded to the [0:180] range with a default of 60
degrees, while <rot_z> is bounded to the [0:360] range with a default of 30
degrees. <scale> controls the scaling of the entire `splot', while <scale_z>
scales the z axis only. Both scales default to 1.0.

   Examples:
            set view 60, 30, 1, 1
            set view ,,0.5

   The first sets all the four default values. The second changes only scale,
to 0.5.

   See also `set ticslevel'.

set vrange
==========

   The `set vrange' command is similar to the `set urange' command.  Please see
`set urange'.

set xlabel
==========

   The `set xlabel' command sets the x-axis label that is centered along the x
axis. Using the optional x,y screen offsets, the label can be placed anywhere
on the plot. `set xlabel' with no parameters clears the label.

   Syntax:
             set xlabel {"<label>"} {<xoff>}{,<yoff>}
             show xlabel

   Specifying constants <xoff> or <yoff> as optional offsets for the label will
move the label <xoff> or <yoff> character screen coordinates. For example,

             set xlabel -1

   will change only the x offset of the xlabel, moving the label roughly one
character width to the left.

   (The EEPIC, Imagen, LaTeX, and TPIC drivers allow \\ in a string to specify
a newline.)

set xrange
==========

   The `set xrange' command sets the horizontal range that will be displayed.
This command turns x axis autoscaling off.

   This range may also be specified on the `plot' command line.

   Syntax:
            set xrange [{<xmin> : <xmax>}]

   where <xmin> and <xmax> terms are constants or expressions.

   Both the <xmin> and <xmax> terms are optional. Anything omitted will not be
changed, so
            set xrange [:10]
   changes xmax to 10 without affecting xmin.

set xtics
=========

   Fine control of the x axis tic marks is possible with the `set xtics'
command. The x-axis tic marks may be turned off with the `set noxtics' command.
They may be turned on (the default state) with `set xtics'.

   Syntax:
             set xtics { {<start>, <incr>{, <end>}} |
                         {({"<label>"} <pos> {, {"<label>"} <pos>}...)} }
             set noxtics
             show xtics

   The <start>, <incr>, <end> form specifies that a series of tics will be
plotted on the x axis between the x values <start> and <end> with an increment
of <incr>. If <end> is not given it is assumed to be infinity. The increment
may be negative. For example,
              set xtics 0,.5,10
   makes tics at 0, 0.5, 1, 1.5, ..., 9.5, 10.

   The ("<label>" <pos>, ...) form allows arbitrary tic positions or
non-numeric tic labels. A set of tics are a set of positions, each with its own
optional label. Note that the label is a string enclosed by quotes, and may be
a constant string, such as "hello", or contain formatting information for the
tic number (which is the same as the position), such as "%3f clients". See `set
format' for more information about this case. The label may even be empty.
Examples:
             set xtics ("low" 0, "medium" 50, "high" 100)
             set xtics (1,2,4,8,16,32,64,128,256,512,1024)
             set xtics ("bottom" 0, "" 10, "top" 20)

   Tics will only be plotted when in range.

   The `set ytics' and `set noytics' commands work identically.  See also the
`set format' command.

set xdtics
==========

   The `set xdtics' commands converts the x axis tic marks to days of the week
where 0=Sun and 6=Sat.  Overflows are converted modulo 7 to dates.

   Examples:
           set xdtics

   Sets x axis tics in days.

   The `set ydtics' `set zdtics' and `set noydtics' `set nozdtics' commands
work identically.  See also the `set format' command.

set xmtics
==========

   The `set xmtics' commands converts the x axis tic marks to months of the
years where 1=Jan and 12=Dec.  Overflows are converted modulo 12 to months.

   Examples:
           set xmtics

   Sets x axis tics into months.

   The `set ymtics' `set zmtics' and `set noymtics' `set nozmtics' commands
work identically.  See also the `set format' command.

set xzeroaxis
=============

   `set xzeroaxis' draws the x-axis. By default, this option is on.  `set
noxzeroaxis' causes GNUPLOT to omit the x-axis.

   Syntax:
            set xzeroaxis
            set noxzeroaxis
            show xzeroaxis

set ylabel
==========

   The `set ylabel' command sets the y-axis label.  The position of this label
depends on the terminal, and can be one of the following three positions (the
position can be adjusted with optional parameters).

   1. Horizontal text flushed left at the top left of the plot.  Terminals that
cannot rotate text will probably use this method.

   2. Vertical text centered vertically at the left of the plot.  Terminals
that can rotate text will probably use this method.

   3. Horizontal text centered vertically at the left of the plot.  The EEPIC,
LaTeX and TPIC drivers use this method. The user must insert line breaks using
\\ to prevent the ylabel from overwriting the plot. To produce a vertical row
of characters, add \\ between every printing character (but this is ugly).

   Syntax:
             set ylabel {"<label>"} {<xoff>}{,<yoff>}
             show ylabel

   With no parameters, the label is cleared. Specifying constants <xoff> or
<yoff> as optional offsets for the label will move the label <xoff> or <yoff>
character screen coordinates. For example,

             set ylabel -1

   will change only the x offset of the ylabel, moving the label roughly one
character width left of its default position. This is especially useful with
the LaTeX driver.

   (The EEPIC, Imagen, LaTeX, and TPIC drivers allow \\ in a string to specify
a newline.)

set yrange
==========

   The `set yrange' command sets the vertical range that will be displayed.
This command turns y axis autoscaling off.

   This range may also be specified on the `plot' command line.

   Syntax:
            set yrange [{<ymin> : <ymax>}]

   where <ymin> and <ymax> terms are constants or expressions.

   Both the <ymin> and <ymax> terms are optional. Anything omitted will not be
changed, so
            set yrange [:10]
   changes ymax to 10 without affecting ymin.

set ytics
=========

   The `set ytics' and `set noytics' commands are similar to the `set xtics'
and `set noxtics' commands. Please see `set xtics'.

set ydtics
==========

   The `set ydtics' and `set noydtics' commands are similar to the `set xdtics'
and `set noxdtics' commands. Please see `set xdtics'.

set ymtics
==========

   The `set ymtics' and `set noymtics' commands are similar to the `set xmtics'
and `set noxmtics' commands. Please see `set xmtics'.

set yzeroaxis
=============

   `set yzeroaxis' draws the y-axis. By default, this option is on.  `set
noyzeroaxis' causes GNUPLOT to omit the y-axis.

   Syntax:
            set yzeroaxis
            set noyzeroaxis
            show yzeroaxis

set zero
========

   The `zero' value is the default threshold for values approaching 0.0.
GNUPLOT will not plot a point if its imaginary part is greater in magnitude
than the `zero' threshold. Axis ranges cannot be less than `zero'. The default
`zero' value is 1e-8. This can be changed with the `set zero' command.

   Syntax:
            set zero <expression>
            show zero

set zeroaxis
============

   `set zeroaxis' draws the x-axis and y-axis. By default, this option is on.
`set nozeroaxis' causes GNUPLOT to omit the axes, and is equivalent to `set
noxzeroaxis; set noyzeroaxis.'

   Syntax:
            set zeroaxis
            set nozeroaxis
            show zeroaxis
   See `set xzeroaxis' and `set yzeroaxis'.

set zlabel
==========

   The `set zlabel' command sets the z-axis label that is centered along the z
axis. Using the optional x,y screen offsets, the label can be placed anywhere
on the plot. `set zlabel' with no parameters clears the label.

   Syntax:
             set zlabel {"<label>"} {<xoff>}{,<yoff>}
             show zlabel

   Specifying constants <xoff> or <yoff> as optional offsets for the label will
move the label <xoff> or <yoff> character screen coordinates. For example,

             set zlabel ,1

   will change only the y offset of the zlabel, moving the label roughly one
character height up.

   The zlabel will be drawn whenever surfaces or contours are plotted, in the
space above the grid level.

   (The EEPIC, Imagen, LaTeX, and TPIC drivers allow \\ in a string to specify
a newline.)

set zrange
==========

   The `set zrange' command sets the vertical range that will be displayed.
This command turns z axis autoscaling off.  The zrange is used only by `splot'
and is ignored by `plot'.

   This range may also be specified on the `splot' command line.

   Syntax:
            set zrange [{<zmin> : <zmax>}]

   where <zmin> and <zmax> terms are constants or expressions.

   Both the <zmin> and <zmax> terms are optional. Anything omitted will not be
changed, so
            set zrange [2:]
   changes zmin to 2 without affecting zmax.

set ztics
=========

   The `set ztics' and `set noztics' commands are similar to the `set xtics'
and `set noxtics' commands. Please see `set xtics'.

set zdtics
==========

   The `set zdtics' and `set nozdtics' commands are similar to the `set xdtics'
and `set noxdtics' commands. Please see `set xdtics'.

set zmtics
==========

   The `set zmtics' and `set nozmtics' commands are similar to the `set xmtics'
and `set noxmtics' commands. Please see `set xmtics'.

shell
*****

   The `shell' command spawns an interactive shell. To return to GNUPLOT, type
`logout' if using VMS, `exit' or the END-OF-FILE character if using Unix,
`endcli' if using AmigaDOS, or `exit' if using MS-DOS or OS/2.

   A single shell command may be spawned by preceding it with the !  character
($ if using VMS) at the beginning of a command line.  Control will return
immediately to GNUPLOT after this command is executed. For example, in VMS,
AmigaDOS, MS-DOS or OS/2,

         ! dir

   prints a directory listing and then returns to GNUPLOT.

   On an Atari, the `!' command first checks whether a shell is already loaded
and uses it, if available. This is practical if GNUPLOT is run from `gulam',
for example.

splot
*****

   Three-dimensional surface and contour plotting is available in GNUPLOT with
the `splot' command. See the `plot' command for features common to the `plot'
command.

   See also `set contour', `set cntrparam', and `set surface'.

Binary Data
===========

   Gnuplot will dynamically determine if a datafile is ASCII or binary.  ASCII
data files are discussed in the `plot' section.  For three dimensions, single
precision floats are stored as follows:

          <ncols> <x0> <x1> <x2> ...
          <y0> <z0,0> <z0,1> <z0,2> ...
          <y1> <z1,0> <z1,1> <z1,2> ...

   which is converted into triplet:

          <x0> <y0> <z0,0>
          <x0> <y1> <z0,1>
          <x0> <y2> <z0,2>

          <x1> <y0> <z1,0>
          <x1> <y1> <z1,1>
          <x1> <y2> <z1,2>

   These triplets are then converted into gnuplot iso_curves and then uses
gnuplot to do the rest of the plotting.

   A collection of matrix and vector manipulation routines (in C) are provided
in `gnubin.c'.  The routine to write binary data is

     int fwrite_matrix(file,m,nrl,nrl,ncl,nch,row_title,column_title)

   An example of using these routines is provided in the file `bf_test.c'.  The
corresponding demo file is `demo/binary.dem'.

start-up
********

   When GNUPLOT is run, it looks for an initialization file to load.  This file
is called `.gnuplot' on Unix and AmigaDOS systems, and `GNUPLOT.INI' on other
systems. If this file is not found in the current directory, the program will
look for it in the home directory (under AmigaDOS, AtariTOS, MS-DOS and OS/2,
the environment variable GNUPLOT should contain the name of this directory).
Note: if NOCWDRC is defined during the installation, GNUPLOT will not read from
the current directory.

   If this file is found, GNUPLOT executes the commands in this file.  This is
most useful for setting the terminal type and defining any functions or
variables that are used often.

substitution
************

   Command-line substitution is specified by a system command enclosed in
backquotes. This command is spawned and the output it produces replaces the
name of the command (and backquotes) on the command line.

   Newlines in the output produced by the spawned command are replaced with
blanks.

   Command-line substitution can be used anywhere on the GNUPLOT command line.

   Example:

   This will run the program `leastsq' and replace `leastsq' (including
backquotes) on the command line with its output:

             f(x) = `leastsq'

   or, in VMS

             f(x) = `run leastsq'

user-defined
************

   New user-defined variables and functions of one through five variables may
be declared and used anywhere.

   User-defined function syntax:
            <function-name> ( <dummy1> {,<dummy2> {, ...} } ) = <expression>

   where <expression> is defined in terms of <dummy1> through <dummy5>.

   User-defined variable syntax:
            <variable-name> = <constant-expression>

   Examples:
            w = 2
            q = floor(tan(pi/2 - 0.1))
            f(x) = sin(w*x)
            sinc(x) = sin(pi*x)/(pi*x)
            delta(t) = (t == 0)
            ramp(t) = (t > 0) ? t : 0
            min(a,b) = (a < b) ? a : b
            comb(n,k) = n!/(k!*(n-k)!)
            len3d(x,y,z) = sqrt(x*x+y*y+z*z)

   Note that the variable `pi' is already defined.

   See `show functions' and `show variables'.

bugs
****

   The bessel functions do not work for complex arguments.

   The gamma function does not work for complex arguments.

   There is a bug in the stdio library for old Sun operating systems (SunOS
Sys4-3.2). The "%g" format for 'printf' sometimes incorrectly prints numbers
(e.g., 200000.0 as "2"). Thus, tic mark labels may be incorrect on a Sun4
version of GNUPLOT. A work-around is to rescale the data or use the `set
format' command to change the tic mark format to "%7.0f" or some other
appropriate format. This appears to have been fixed in SunOS 4.0.

   Another bug: On a Sun3 under SunOS 4.0, and on Sun4's under Sys4-3.2 and
SunOS 4.0, the 'sscanf' routine incorrectly parses "00 12" with the format "%f
%f" and reads 0 and 0 instead of 0 and 12. This affects data input. If the data
file contains x coordinates that are zero but are specified like '00', '000',
etc, then you will read the wrong y values. Check any data files or upgrade the
SunOS.  It appears to have been fixed in SunOS 4.1.1.

   Microsoft C 5.1 has a nasty bug associated with the %g format for printf.
When any of the formats "%.2g", "%.1g", "%.0g", "%.g" are used, printf will
incorrectly print numbers in the range 1e-4 to 1e-1.  Numbers that should be
printed in the %e format are incorrectly printed in the %f format, with the
wrong number of zeros after the decimal point.

   To work around this problem, use the %e or %f formats explicitly.

   GNUPLOT, when compiled with Microsoft C, did not work correctly on two VGA
displays that were tested. The CGA, EGA and VGA drivers should probably be
rewritten to use the Microsoft C graphics library.  GNUPLOT compiled with
Borland C++ uses the Turbo C graphics drivers and does work correctly with VGA
displays.

   VAX/VMS 4.7 C compiler release 2.4 also has a poorly implemented %g format
for printf. The numbers are printed numerically correct, but may not be in the
requested format. The K&R second edition says that for the %g format, %e is
used if the exponent is less than -4 or greater than or equal to the precision.
The VAX uses %e format if the exponent is less than -1. The VAX appears to take
no notice of the precision when deciding whether to use %e or %f for numbers
less than 1.  To work around this problem, use the %e or %f formats explicitly.
From the VAX C 2.4 release notes: e,E,f,F,g,G  Result will always contain a
decimal  point.  For g and G, trailing zeros will not be removed from the
result.

   VAX/VMS 5.2 C compiler release 3.0 has a slightly better implemented %g
format than release 2.4, but not much. Trailing decimal points are now removed,
but trailing zeros are still not removed from %g numbers in exponential format.

   ULTRIX X11R3 has a bug that causes the X11 driver to display "every other"
plot.  The bug seems to be fixed in DEC's release of X11R4 so newer releases of
ULTRIX don't seem to have the problem.  Solutions for older sites include
upgrading the X11 libraries (from DEC or direct from MIT) or defining
ULTRIX_KLUDGE when compiling the x11.trm file.  Note that the kludge is not an
ideal fix, however.

   The constant HUGE was incorrectly defined in the NeXT OS 2.0 operating
system.  HUGE should be set to 1e38 in plot.h. This error has been corrected in
the 2.1 version of NeXT OS.

   Some older models of HP plotters do not have a page eject command 'PG'.  The
current HPGL driver uses this command in HPGL_reset.  This may need to be
removed for these plotters.  The current PCL5 driver uses HPGL/2 for text as
well as graphics.  This should be modified to use scalable PCL fonts.

   On the Atari version, it is not possible to send output directly to the
printer (using `/dev/lp' as output file), since CRs are added to LFs in binary
output. As a workaround write the output to a file and copy it to the printer
afterwards using a shell command.

   Please report any bugs to bug-gnuplot@dartmouth.edu.