#| -*-Scheme-*-

$Id$

Copyright 2006 Massachusetts Institute of Technology

This program is free software; you can redistribute it and/or modify
it under the terms of the GNU General Public License as published by
the Free Software Foundation; either version 2 of the License, or (at
your option) any later version.

This program is distributed in the hope that it will be useful, but
WITHOUT ANY WARRANTY; without even the implied warranty of
MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
General Public License for more details.

You should have received a copy of the GNU General Public License
along with this program; if not, write to the Free Software
Foundation, Inc., 51 Franklin St, Fifth Floor, Boston, MA 02110-1301,
USA.

|#

;;;; Boolean constraint types

(declare (usual-integrations))

(define cp:B=~A
  (cp:make-constraint-type 'B=~A '(b a)
    (lambda (constraint)
      (let ((b (cp:get-connector constraint 'b))
	    (a (cp:get-connector constraint 'a)))
	(cond ((cp:has-value? a)
	       (cp:set-value b
			     (not (cp:value-of a))
			     (list a)
			     constraint))
	      ((cp:has-value? b)
	       (cp:set-value a
			     (not (cp:value-of b))
			     (list b)
			     constraint)))))))

(define cp:C=A^B
  (cp:make-constraint-type 'C=A^B '(c b a)
    (lambda (constraint)
      (let ((c (cp:get-connector constraint 'c))
	    (b (cp:get-connector constraint 'b))
	    (a (cp:get-connector constraint 'a)))
	(cond ((and (cp:has-value? a)
		    (cp:has-value? b))
	       (cp:set-value c
			     (and (cp:value-of a) (cp:value-of b))
			     (list a b)
			     constraint))
	      ((not (cp:has-value? c))
	       (cond ((cp:value-is? a #f)
		      (cp:set-value c #f (list a) constraint))
		     ((cp:value-is? b #f)
		      (cp:set-value c #f (list b) constraint))))
	      ((cp:value-is? c #f)
	       (cond ((cp:value-is? a #t)
		      (cp:set-value b #f (list a c) constraint))
		     ((cp:value-is? b #t)
		      (cp:set-value a #f (list b c) constraint))))
	      (else
	       (cp:set-value a #t (list c) constraint)
	       (cp:set-value b #t (list c) constraint)))))))

(define cp:C=AvB
  (cp:make-constraint-type 'C=AvB '(c b a)
    (lambda (constraint)
      (let ((c (cp:get-connector constraint 'c))
	    (b (cp:get-connector constraint 'b))
	    (a (cp:get-connector constraint 'a)))
	(cond ((and (cp:has-value? a)
		    (cp:has-value? b))
	       (cp:set-value c
			     (or (cp:value-of a) (cp:value-of b))
			     (list a b)
			     constraint))
	      ((not (cp:has-value? c))
	       (cond ((cp:value-is? a #t)
		      (cp:set-value c #t (list a) constraint))
		     ((cp:value-is? b #t)
		      (cp:set-value c #t (list b) constraint))))
	      ((cp:value-is? c #t)
	       (cond ((cp:value-is? a #f)
		      (cp:set-value b #t (list a c) constraint))
		     ((cp:value-is? b #f)
		      (cp:set-value a #t (list b c) constraint))))
	      (else
	       (cp:set-value a #f (list c) constraint)
	       (cp:set-value b #f (list c) constraint)))))))